Дебет-Кредит
Украинский бухгалтерский еженедельник
#04'2002: Практичная бухгалтерия - Автоматически

Автоматизации бухучёта: Excel

Урок 23
Автоматизация бухгалтерского и налогового учета основных средств с помощью EXCEL

Владимир ЛАВРЕНОВ


Предыдущие уроки "Автоматизации бухучёта: Excel"l

В формуле расчета месячной амортизации, приведенной на прошлом уроке, одним из основных аргументов является переоцененная стоимость объекта основных средств. Можно сказать, что для корректного автоматического расчета амортизации необходима регулярная оценка объекта ОС.

Международные стандарты бухгалтерского учета устанавливают возможность переоценки всего класса ОС на беспрерывной основе, если такая переоценка осуществляется своевременно и за короткий промежуток времени. Реализованный в таблице принцип тоже предполагает ежемесячное определение показателей бухгалтерского и налогового учета ОС. На этом уроке будут рассмотрены особенности учета переоценки.

Переоценка с помощью электронной таблицы

При переоценке необходимо определять справедливую стоимость, которая, как правило, является рыночной ценой объекта ОС или определяется с помощью экспертной оценки. Если данных о рыночной стоимости ОС нет, то в этом случае объекты ОС оцениваются по текущей себестоимости приобретения подобного актива. Данные таких оценок заносятся в графу "Справедливая стоимость" таблицы вручную (рис. 1)1. А вот заключение о необходимости переоценки будет принято автоматически.

Рисунок 1

Для учета данных переоценки в таблице выделен раздел "Переоценка" (столбцы Т:АВ, рис. 1).

Если переоценка не проводится, данные граф этого раздела совпадают с данными аналогичных граф раздела "Бухучет". Однако если введенное вручную значение справедливой стоимости (D14, рис. 1) будет значительно отличаться от остаточной стоимости (R14), таблица автоматически отреагирует на это и будет мгновенно произведен новый расчет всех показателей (U14:AB14). Так как методика их расчета значительно отличается от расчета показателей раздела "Бухучет", рассмотрим ее подробнее на примере заполнения граф.

Символ переоценки

В ячейках этой графы фиксируется факт проведения переоценки. В качестве индикатора того, что на первое число текущего периода произведена переоценка, служат символы "У" (уценка) и "Д" (дооценка), которые появляются в ячейках соответствующей графы. Запишите в ячейку U12 формулу:

"=ЕСЛИ(ИЛИ(A12=0;D12=0);0;ЕСЛИ((D12-R12)/D12>0,1;"Д";
ЕСЛИ((D12-R12)/D12<-0,1;"У";"")))".

Например, экспертной оценкой установлено, что на 1 января 2001 г. справедливая стоимость факса Sharp FO50 составила 1750 грн. Так как введенное в ячейку D14 значение "1750" более чем на 10% превышает значение остаточной стоимости на эту же дату (R14), в ячейке U14 появится символ "Д".

"В случае переоценки объекта основных средств на ту же дату осуществляется переоценка всех объектов группы основных средств, к которой принадлежит данный объект" (п. 16 Стандарта 7).

Требование Стандарта, изложенное в п. 16, несложно выполнить, если использовать в таблице команду "Автофильтр" (меню "Данные" - "Фильтр").

Вот когда можно использовать данные графы "Группа ОС". Щелкните стрелку автофильтра (ячейка L10, рис. 2) и укажите код объекта ОС, для которого проводится переоценка (для приведенного варианта - 106). Затем с помощью фильтра графы "Дата учета" укажите дату, на которую производится переоценка (1 января 2001 г.). В результате вы получите доступ только к тем данным, которые удовлетворяют выбранным параметрам. А дальше берите в руки прайсы, данные экспертной оценки, и вводите их в ячейки графы "Справедливая стоимость".

Рисунок 2

Индекс переоценки

Пункт 17 Стандарта гласит: "Индекс переоценки определяется делением справедливой стоимости переоцениваемого объекта на его остаточную стоимость".

В таблице расчет индекса переоценки производится только в том случае, если в соседней ячейке появляется символ "Д" или "У". В любом другом случае он равен 1.

Это условие обеспечивается формулой, введенной в ячейку V12:

"=ЕСЛИ(A12=0;0;ЕСЛИ(ИЛИ(И(U12="Д";R12>0,1);
U12="У");D12/R12;1))"2

В ячейку V11 запишите значение 1 (рис. 2).

Первоначальная стоимость

Фактически в эту графу должна записываться переоцененная стоимость, которая определяется умножением первоначальной стоимости на индекс переоценки. Однако такой вариант не подходит, если на момент переоценки остаточная стоимость будет равна нулю. Выход из положения предусмотрен в п. 17 Стандарта 7:

"Если остаточная стоимость объекта основных средств равна нулю, то его переоцененная остаточная стоимость определяется добавлением справедливой стоимости этого объекта к его первичной (переоцененной) стоимости без изменения суммы износа объекта".

Однако здесь в Стандарте неточность. В данном случае, полагаю, приведена формула расчета переоцененной первичной стоимости, а не остаточной. Проверьте сами: если до переоценки остаточная стоимость объекта основных средств равна нулю (Z27), значит, сумма износа равна первоначальной (предварительно переоцененной) стоимости (значение X27 равно W27). После переоценки остаточная стоимость должна быть равна справедливой стоимости (значение Z27 равно D27, см. вставку на рис. 3). Для приведенного на рис. 3 примера переоцененная первичная стоимость будет равна 2519,23 (2019,23 + 500).

Рисунок 3

Данная формула учитывает эту особенность:

"=ЕСЛИ(V12<>1;V12*W11;ЕСЛИ(И(R12<0,1;D12>0); D12+W11;W11))".

Введите ее в ячейку W12.

В ячейку запишите: "=P11*V11".

Переоцененная сумма износа

Стандарт устанавливает, что переоцененная сумма износа объекта ОС определяется умножением суммы износа на индекс переоценки. В отличие от данных графы "Месячная амортизация" (столбец Q), в ячейках графы "Износ на начало периода" записывается износ нарастающим итогом и показывает суммарную амортизацию (т. е. износ) на соответствующую дату после переоценки.

Формула в ячейке Х12 простая: "=(X11+Q12)*V12".

Сумма переоценки и остаточная (переоцененная) стоимость

Стандарт не устанавливает такой показатель, как сумма переоценки, однако ее подсчет поможет вам контролировать правильность определения дополнительного капитала и изменения доходов и расходов от переоценки.

Y12: "=ЕСЛИ(И(R12<0,1;D12>0);D12;D12-R12)".

Запишите в ячейку Z12 формулу переоцененной остаточной стоимости: "=W12-X12".

Изменение дополнительного капитала

Один из самых ответственных этапов при переоценке - определение суммы изменения дополнительного капитала (ДК). Разберем рекомендации Стандарта на примерах, используя приведенную в таблице 1 общую формулу расчета изменения ДК (она должна быть введена в ячейку АА12).

Для удобства понимания она разбита на логические части. При записи этой формулы внесите все (!) символы, приведенные в таблице 1.

Таблица 1

Фрагменты формулы
1 ЕСЛИ(ИЛИ(И(U12="Д";СУММ($Y$11:Y11)>=0);
2 (U12="У";СУММ($Y$11:Y11)>0;ABS(Y12)<СУММ ($Y$11:Y11)));Y12;
3 ЕСЛИ(И(U12="Д";СУММ($Y$11:Y11)<0; Y12>ABS(СУММ($Y$11:Y11)));
Y12-ABS(СУММ($Y$11:Y11));
4 ЕСЛИ(И(U12="У";СУММ($Y$11:Y11)>0; ABS(Y12)>СУММ($Y$11:Y11));-СУММ($Y$11:Y11);
5 0)))

Итак, согласно Стандарту 7, дополнительный капитал при переоценке изменяется в пяти случаях, а именно:

1) при первой переоценке, если при этом производится дооценка (рис. 4). При этом сумма дооценки остаточной стоимости включается в состав ДК. В примере (рис. 4) на момент переоценки (01.01.2001 г.) остаточная стоимость - 1516,67, переоцененная о. с. - 1700,00, увеличение ДК - 183,33.

Рисунок 4

2) при последующей дооценке, если сумма предыдущих дооценок превышает сумму предыдущих уценок (рис. 5).

Рисунок 5

Выполнение этих двух условий обеспечивает фрагмент №1 формулы (см. таблицу 1):

"ЕСЛИ(ИЛИ(И(U12= "Д";СУММ($Y$11:Y11)>=0);".

Обратите внимание на аргумент "СУММ($Y$11:Y11)". Такая запись суммирует данные столбца начиная с фиксированной ячейки $Y$11 до ячейки текущей строки.

В примере дооценки (Y18=236,36, рис. 5), которая была проведена 01.05.2001 г., предшествовали две переоценки (дооценка Y14=183,33 и уценка Y16=138,46). Поэтому вся сумма последующей дооценки идет на увеличение ДК (АА18=236,36);

3) при последующей уценке, если сумма предыдущих дооценок превышает сумму предыдущих уценок, а величина уценки меньше этого превышения (рис. 5)3.

Фрагмент №2 обеспечивает выполнение данного условия:

"И(U12="У";СУММ($Y$11:Y11)>0;
ABS(Y12)<СУММ ($Y$11:Y11)));Y12;".

В нем использована функция абсолютной величины ABS для сравнения отрицательных значений переоценки (суммы уценок) и положительных (суммы дооценок).

Например, уценка, проведенная 01.03.2001 г.,4 меньше, чем предыдущие переоценки (для упрощения приведена только дооценка, Y14). Поэтому дополнительный капитал будет уменьшен на всю сумму такой уценки.

4) при последующей дооценке, если сумма предыдущих уценок превышает сумму предыдущих дооценок, а величина дооценки больше этого превышения.

Фрагмент №3 обеспечивает выполнение данного условия:

ЕСЛИ(И(U12="Д";СУММ($Y$11:Y11)<0; Y12>
ABS(СУММ($Y$11:Y11))); ABS(СУММ($Y$11:Y12);.

Стандарт дает несколько запутанный расчет дополнительного капитала. Для этого случая годится простая формула: при дооценке дополнительный капитал увеличится на сумму всех переоценок, включая текущую дооценку. Например, 5 мая 2001 г. была проведена дооценка на сумму 318,18 грн (Y18, рис. 6), при этом в предыдущих переоценках уценки превышали дооценки на 55,13 грн (дооценка Y14=183,33, уценка Y16= 238,46). Сумма всех переоценок равна 263,05 грн (183,33 - 238,46 + 318,18).

Проверьте: согласно Стандарту, для этого варианта превышение предыдущих уценок над предыдущими дооценками увеличивает доходы на 55,13 грн (238,46 - 183,33), остальная же часть текущей дооценки увеличивает ДК (318,18 - 55,13 = 263,05).

5) при последующей уценке, если сумма предыдущих дооценок превышает сумму предыдущих уценок, а величина уценки больше этого превышения.

При этом дополнительный капитал уменьшается на величину превышения суммы предыдущих дооценок над суммой предыдущих уценок. Обеспечивает выполнение этого условия фрагмент формулы №4:

"ЕСЛИ(И(U12="У";СУММ($Y$11:Y11)>0;
ABS(Y12)>СУММ ($Y$11:Y11));-СУММ($Y$11:Y11)".

Например, 01.03.2001 г. была проведена уценка на сумму 238,48 грн. (Y16, рис. 6), при этом предыдущие дооценки превышали сумму предыдущих уценок на 183,33 грн (Y14). Следовательно, дополнительный капитал уменьшится только на 183,33 грн (АА16, рис. 6).

Рисунок 6

Все другие варианты переоценки дополнительный капитал не изменяют.

Как переоценка влияет на расходы и доходы

Изменение этих показателей отражается в графе "Включение в расходы или доходы" ($АВ:$AB):

"Сумма уценки остаточной стоимости объекта основных средств включается в состав расходов, кроме случаев, которые приведены в пункте 20" (п. 19 Стандарта 7).

При внимательном прочтении Стандарта 7 нетрудно увидеть, что величина изменения доходов или расходов от проведенной переоценки равна разнице между суммой переоценки и изменением дополнительного капитала. Определение дополнительного капитала мы подробно рассмотрели в предыдущем разделе, в котором были проанализированы ограничения пункта 20 Стандарта. Данное утверждение проиллюстрировано на рис. 6.

Проведенная 1 марта 2001 г. уценка на сумму 238,46 грн привела к уменьшению дополнительного капитала на сумму 183,33 грн, а также к увеличению расходов периода на сумму 55,13 грн (ячейка АВ16, рис. 6).

Проведенная 1 мая 2001 г. дооценка на сумму 318,18 грн привела к увеличению доходов периода на сумму 55,13 грн (ячейка АВ18).

Поэтому в ячейку АВ12 введите простую формулу:

"=Y12-AA12".

Что произойдет при выбытии переоцененных ОС

Мы рассмотрели варианты расчета изменения дополнительного капитала в отчетном периоде. Для определения общей величины ДК нарастающим итогом используется графа "Дополнительный капитал" (столбец S), в которой отражаются итоговые данные на первое число месяца.

"При выбытии объектов основных средств, которые раньше были переоценены, превышение сумм предыдущих дооценок над суммой предыдущих уценок остаточной стоимости данного объекта основных средств включается в состав нераспределенной прибыли с одновременным уменьшением дополнительного капитала" (п. 21 Стандарта 7).

Для того чтобы в таблице автоматически отличать вывод из эксплуатации объекта ОС от его выбытия или ликвидации, используется графа "Стоимость реализации"5.

Для обеспечения этих требований введите в ячейку S12 формулу:

"=ЕСЛИ(A11=0;0;ЕСЛИ(И(ЕЧИСЛО(G11)=ИСТИНА;
СУММ ($Y$11:Y11)>0);

S11-СУММ($Y$11:Y11);S11+AA11))".

Например, 12 сентября 2001 г. объект ОС был выведен из эксплуатации (F22, рис. 7).

Рисунок 7

Для фиксации этого события введите в соответствующую ячейку графы "Стоимость реализации" числовое значение (если это продажа - стоимость реализации, если ликвидация - нулевое значение). При этом на 01.10.2001 г. ДК уменьшится на 263,05 грн - сумму всех переоценок этого объекта (СУММ(Y11:Y22), рис. 7).

Согласитесь, с использованием электронной таблицы требования Стандарта становятся и понятнее, и нагляднее. Из анализа табличной переоценки можно сделать два очевидных вывода:

- если в результате всех переоценок объект ОС был дооценен (Y14:Y18, рис. 7) - на эту же сумму изменится дополнительный капитал (АА14:АА18). При этом увеличение расходов за весь период будет равно увеличениям доходов (АВ14:АВ18);

- если в результате всех переоценок объект ОС был уценен (Y14:Y16, рис. 7) - на эту же сумму увеличатся расходы (АА14:АА16). При этом дополнительный капитал не изменится (АА14:АА16).

Исправления в формулах

Во всех формулах, приведенных на уроке №22, в которых есть аргумент "R11<=J11", замените его аргументом "А12=0". Измените формулы в ячейках:

А12 - "=ЕСЛИ(ИЛИ(ЕЧИСЛО(G11)=ИСТИНА;R11-0,1<=J11);0;A11)";
F12 - "=ЕСЛИ(ИЛИ(A12=0;E12>0);0;F11)";
I12 - "=ЕСЛИ(A12=0;0;ЕСЛИ(ИЛИ(J11<>J12;K11<>K12;V11<>1);
I11-O11;I11)).

Это даст возможность "обнулять" последнюю строку таблицы при выбытии объекта ОС или достижении остаточной стоимостью величины ликвидационной стоимости.


Примечания:

1 Для компактности столбцы E, F, G, H скрыты.

2В формулы этого материала включен аргумент "R12>0,1", который фактически сравнивает значение ячейки с нулем. Это вызвано тем, что при расчете амортизации ОС используются методы, не позволяющие остаточной стоимости достичь "абсолютного нуля".

3Знак "-" (минус) перед значением в ячейках Y16, АА16, АВ16 (рис. 6) обозначает, соответственно, что это сумма уценки, величина уменьшения дополнительного капитала, величина расходов.

4Для большей наглядности в приведенных примерах автор отошел от требования Стандарта проводить переоценку на дату баланса.

5Данные этой графы будут использоваться также при автоматизации налогового учета ОС.


Следующий урок

© 2002
"Дебет-Кредит"
Редакция: debet-kredit@gc.kiev.ua