Нове число  Дебет-Кредит
  Український бухгалтерський тижневик
#51'2001: Практична бухгалтерія - Автоматично

Автоматизації бухобліку: Excel

Автоматизація бухгалтерського і податкового обліку основних засобів з допомогою EXCEL. Урок 21

Володимир ЛАВРЄНОВ


Попередні уроки "Автоматизації бухобліку: Excel"

Прийняття Положення (стандарту) бухгалтерського обліку 7 "Основні засоби" докорінно змінило методологію їх обліку. Ця стаття не передбачає розгляду особливостей усіх стадій обліку ОЗ. Головна увага буде зосереджена на найбільш трудомістких (з погляду розрахунку) етапах обліку основних засобів:

- вибір методу амортизації та її розрахунок;

- переоцінка ОЗ і її наслідки в бухгалтерському обліку (зміна доходів, витрат і додаткового капіталу);

- індексація вартості ОЗ;

- визначення амортизації в податковому обліку;

- податковий облік індексації і реалізації основних засобів.

Універсальна таблиця обліку основних засобів

Основною проблемою, з якою бухгалтер стикається при обліку основних засобів, є періодичне щомісячне визначення розміру амортизаційних відрахувань, особливо якщо обрано один із непропорційних методів. А якщо підприємство приймає рішення про переоцінку або індексацію, ця робота стає доволі трудомісткою.

Способи розрахунку з використанням комп'ютера, без сумніву, мають величезну перевагу у швидкості обробки даних перед усіма іншими. Облік основних засобів передбачає визначення великої кількості показників як у бухгалтерському, так і в податковому аспекті обліку. Об'єднання в одній таблиці різних блоків розрахунку показників бухгалтерського і податкового обліку приведе до того, що таблиця стане трохи громіздкою, але зате дозволить зробити облік основних засобів більш зрозумілим і контрольованим.

На малюнках 1 і 2 показано загальний вигляд таблиці, у якій створено:

- блок вхідних даних (стовпчики A-J);

- блок "Бухгалтерський облік". У ньому провадиться розрахунок амортизації і зберігаються дані щодо вибраного основного засобу;

- блок "Переоцінка", у якому здійснюється розрахунок уцінок і дооцінок, а також визначаються зв'язані з ними суми доходів (витрат) і зміни додаткового капіталу, які заносяться до балансу;

- блок "Податковий облік", що дозволяє визначати балансову вартість і податкові наслідки при індексації і реалізації об'єкта основних засобів. На малюнку 2 блоки "Бухгалтерський облік" і "Переоцінка" згруповані і згорнуті.

Малюнок 1

Малюнок 2

Для організації обліку для кожного об'єкта основних засобів необхідно виділити деякий масив вільних рядків. Його розмір ви можете визначити цілком довільно виходячи із середнього терміну експлуатації для всіх основних засобів, що обліковуються на підприємстві. При цьому один рядок кожного масиву містить дані за один розрахунковий період.

Доповнювати таблицю новими об'єктами основних засобів можна не звертаючи уваги на їх належність до тієї чи іншої групи ОЗ (у бухгалтерському чи податковому обліку). Адже ви в будь-який момент зможете застосувати фільтр, згрупувати дані в зручному для вас вигляді і побудувати таблицю за будь-яким критерієм.

Вибір методу амортизації

Реформований бухгалтерський облік дав можливість підприємству самостійно провадити амортизаційну політику, визначати найвигідніший для підприємства метод амортизації і терміни експлуатації основних засобів.

У принципі, національний бухоблік припускає використання трьох основних методів амортизації:

- рівномірного нарахування (прямолінійний);

- прискореного нарахування;

- метод використання податкових норм амортизації.

Другий метод містить у собі чотири методи, передбачені П(С)БО 7.

Необхідність вибирати із шести (!) методів амортизації значно ускладнює пошук оптимального. Публікації на цю тему дають численні рекомендації щодо вибору методу, однак переважно вони мають загальний характер і не враховують особливостей експлуатації ОЗ на конкретному підприємстві.

Проблема вибору значно спроститься, якщо зробити попередній аналіз ефективності всіх методів стосовно конкретного об'єкта основних засобів. Excel дозволить одночасно розрахувати амортизацію за всіма методами і зіставити результати за допомогою графіків. Це дасть вам можливість не тільки швидко порівняти їх, варіюючи різні параметри, але й спрогнозувати динаміку зміни вартості об'єкта ОЗ при зміні умов експлуатації.

Для організації обліку і розрахунків параметрів основних засобів створіть окрему книгу, у якій на аркуші Амортизація побудуйте таблицю, показану на малюнку 3.

Малюнок 3

У верхній її частині розташований блок для введення вхідних даних, що використовуються при розрахунку норм амортизації за будь-яким із методів. Дані в комірки G3:N3 (крім комірки L3) вносяться вручну. У комірку L3 треба записати формулу "=K3/12".

Основна розрахункова таблиця містить два масиви даних, на підставі яких і будуть побудовані порівняльні графіки.

Зверніть увагу, що для коректної роботи формул у таблиці використовується рядок 11 ("рік - 0"), у ліву частину якого внесені нульові значення річної амортизації, а в праву - первісна вартість об'єкта основних засобів.

У П(С)БО 7 "Основні засоби" описано формули розрахунку норм амортизації для кожного методу. Excel пропонує набір стандартних формул, які ми можемо використовувати при аналізі амортизації для чотирьох методів, розглянутих у П(С)БО 7.

Прямолінійний метод: просто й неефективно

Для розрахунку амортизації за цим методом в Excel використовується функція "АМР(Стоимость;Остаток;Период)", де

Стоимость - первісна вартість;

Остаток - ліквідаційна вартість;

Период - кількість періодів (років), протягом яких об'єкт амортизується.

За допомогою цієї функції розраховується річна амортизація.

Наприклад, якщо передбачається, що об'єкт амортизуватиметься протягом 5 місяців, то в цьому випадку аргумент Период = 1, а сумарна амортизація за весь період визначиться множенням функції АМР на коефіцієнт 5/12.

Отже, в комірку С12 введіть формулу

"=ЕСЛИ(A12="";"";АМР(I$3;J$3;L$3))".

Функція АМР - найпростіша з використовуваних у Excel, але й можливості для регулювання суми амортизації протягом одного періоду дуже обмежені.

Ось як виглядатиме формула в комірці С12 без використання функції АМР:
"=ЕСЛИ(A12="";"";(I$3-J$3)/L$3)".

Метод зменшення залишкової вартості

Цей метод використовується для забезпечення більш прискореної амортизації. Серед фінансових функцій Excel є кілька функцій, за допомогою яких розраховується амортизація прискореними методами. Запропонована в П(С)БО 7 методика розрахунку за методом зменшення залишкової вартості реалізована в Excel-функції "ДОБ(Стоимость;Остаток;Период;Год;Месяц)", де:

аргументи Стоимость, Остаток, Период - такі ж, як і у функції АМР;

Год - період, для якого обчислюється амортизація. У цьому випадку йдеться про календарний рік, що містить період, який розраховується. Наприклад, період амортизації об'єкта ОЗ дорівнює 5 рокам, амортизація нараховується з 01.09.2001 р. У формулах для всіх місяців 2001 року для аргументу Год використовуватиметься значення 1, для періоду з 01.01.2006 р. до 31.08.2006 р. аргумент Год = 6;

Месяц - це кількість місяців у першому році. Наприклад, якщо об'єкт ОЗ амортизувався 3 місяці, то аргумент Месяц =3. Якщо аргумент Месяц пропущено, то передбачається, що він дорівнює 12.

У комірку D12 введіть формулу

"=ЕСЛИ(A12= "";"";ДОБ(I$3;J$3;L$3;А12))".

У цій формулі аргумент Месяц пропущено, тому що з метою аналізу зручніше оперувати річними нормами амортизації.

Без використання функції ДОБ формула для розрахунку амортизації за цим методом, записана в комірку D12, виглядає так:

=ЕСЛИ(A12="";"";K11*(1-СТЕПЕНЬ(J$3/I$3;1/L$3)).

Прискорене зменшення залишкової вартості - прискорення на старті

Цей запропонований П(С)БО 7 метод не передбачає автоматичного зменшення терміну амортизації об'єкта основних засобів, як може видатися на перший погляд.

Пояснімо застосування методу на прикладі, наведеному на малюнку 3.

Первісна вартість (ВП) - 25000 грн.

Ліквідаційна вартість (ВЛ) - 5000 грн.

Термін корисного використання об'єкта (К) - 8 років.

Отже, згідно з П(С)БО 7, річна норма амортизації (НА) дорівнює подвоєній частці від ділення одиниці на термін корисного використання, тобто НА=2х1/К(2х1/8 = 0,25).

Для першого періоду річна амортизація об'єкта дорівнює: А1 = 25000 х 0,25 = 6250 (мал. 3).

Базою для визначення амортизації протягом другого року експлуатації буде залишкова вартість на початок цього року: ВП2 = ВП - ВЗ1 = 25000 - 6250 = 18750.

Для другого періоду річна амортизація об'єкта дорівнює: А2 = ВП2 х НА = 18750 х 0,25 = 4687,5.

і так далі, до досягнення ліквідаційної вартості - 5000 грн.

Як бачимо, об'єкт із такими початковими даними замість 8 років, визначених для його корисного використання, буде амортизований до ліквідаційної вартості за 6 років.

Саме така методика розрахунку амортизації використовується Excel-функцією

ДДОБ(Стоимость;Остаток;Период;Год;Коеффициент), де перші чотири аргументи - подібні до аргументів наведених вище функцій;

Коеффициент - норма амортизації.

Якщо аргумент пропущено, то він береться за 2.

Хоча П(С)БО 7 і не передбачає, крім коефіцієнта 2, жодного іншого, міжнародна практика бухгалтерського обліку дозволяє використовувати різні його значення. Наприклад, якщо ви не хочете збільшувати норму амортизації удвічі, а тільки в півтора рази, коефіцієнт дорівнюватиме 1,5. Ми ж можемо сміливо його пропускати.

А тепер введіть у комірку Е12 формулу

"=ЕСЛИ(A12="";"";ДДОБ(I$3;J$3;L$3;А12))".

Якщо ж ви волієте не використовувати функцію ДДОБ, запишіть у комірку Е12 таку формулу:

"=ЕСЛИ(A12="";"";L11*2/L$3)".

Кумулятивний метод: повторення пройденого

Незважаючи на принципову відмінність цього методу від методу зменшення залишкової вартості, результати відрізнятимуться ненабагато. (У цьому ви пересвідчитеся, коли побудуєте графіки.)

Визначення річної амортизації за кумулятивним методом реалізується за допомогою функції

АМГД(Стоимость;Остаток;Период;Год).

Значення аргументів у цій функції аналогічні до наведених вище. При використанні функції АМГД слід пам'ятати, що під аргументом Год мається на увазі період часу, що дорівнює календарному року, початком якого є день початку амортизації. Наприклад, амортизація на об'єкт ОЗ нараховується з 01.09.2001 р. Для місяців у період з 01.09.2001 р. до 31.08.2002 р. аргумент Год =1, для періоду з 01.09.2003 р. до 31.08.2004 р. аргумент Год =3.

Тепер введіть у комірку F12 формулу

=ЕСЛИ(A12="";"";АМГД(I$3;J$3;L$3;А12)).

Як альтернативу використанню функції АМГД при визначенні амортизації за цим методом можна ввести в комірку F12 таку формулу:

=ЕСЛИ(A12="";"";(I$3-J$3)*(L$3+A$12-A12)*2/(1+L$3)/L$3).

Виробничий метод: чим більше продукції, тим більша амортизація

Вибір методу амортизації треба узгоджувати з характером економічних вигод, які підприємство очікує одержати від експлуатації об'єкта основних засобів. Виробничий метод або метод суми одиниць продукції (так він називається в міжнародних стандартах бухгалтерського обліку) є одним з методів прискореної амортизації. Його застосування виправдане для підприємств, для яких важливо в управлінському обліку відслідковувати залежність зносу устаткування від кількості продукції, що випускається з його використанням.

Аналога цього методу в базі фінансових функцій Excel немає. Тому розрахунок амортизації за цим методом буде зроблено з використанням методики, викладеної в П(С)БО 7.

У цьому випадку базовою розрахунковою величиною є місячна сума амортизації. Вона визначається як добуток фактичного місячного обсягу продукції (робіт, послуг) та виробничої ставки амортизації. Остання обчислюється діленням амортизованої вартості на загальний обсяг продукції, яку підприємство очікує виготовити з використанням цього об'єкта ОЗ.

Для автоматизації аналізу в основну таблицю введіть графу "Фактичний обсяг продукції" (мал. 3), у яку занесіть дані річного обсягу продукції1. Річну амортизацію, розраховану за виробничим методом для першого року, визначимо за формулою

"=ЕСЛИ(A12="";"";B12*(I$3-J$3)/M$3)", увівши її в комірку G12.

Податковий метод: залишіть для податкового обліку

Цей метод усім знайомий, і його перенесення для визначення амортизації в бухгалтерському обліку не становитиме для вас жодних складнощів (зараз я не говорю про доцільність його практичного використання). Достатньо, з урахуванням належності об'єкта до певної групи ОЗ, використовувати квартальні норми амортизації, збільшивши їх у 4 рази.

Отже, введіть у комірку Н12 таку формулу:

=ЕСЛИ(A12="";""; ЕСЛИ(H$3=1;O11*0,05;ЕСЛИ(H$3=2;
O11* 0,25;ЕСЛИ(H$3=3;O11*0,15;0)))).

Як використовувати аналітичну таблицю

Як звичайно в наших уроках, розрахункові формули в таблицях побудовані таким чином, щоб досить було ввести їх тільки в перший рядок таблиці і скопіювати їх униз на достатню кількість рядків. В аналітичній таблиці (мал. 3) для одержання довідкових результатів місячної амортизації за кожним методом введена додаткова графа. Вона виділена сірим фоном. У комірці I12 записана така формула: =ЕСЛИ(C12="";"";ЕСЛИ(G$3=1; C12/12;ЕСЛИ(G$3=2;D12/12;
ЕСЛИ(G$3=3;E12/12;ЕСЛИ(G$3=4;
F12/12;ЕСЛИ(G$3=5;G12/12;H12/12)))))).

Ліва частина таблиці вже заповнена формулами розрахунку норм амортизації. Тепер уведіть формулу в комірку А12 - "=ЕСЛИ($L$3>A11;A11+1;"")", що обнулює порядковий номер року амортизації, якщо він більший від терміну корисного використання.

Формули правої частини таблиці прості. Наприклад, у комірці J12 записана формула "=ЕСЛИ(A12="";"";ЕСЛИ(J11<C12;0;J11-C12))", в інших комірках 12-го рядка вони аналогічні.

Тепер залишилося виділити 12-й рядок таблиці і скопіювати її, наприклад, на 20 рядків униз (думаю, для аналізу досить буде 20-річного періоду). Якщо у вас уже внесена вихідна інформація, то в таблиці відобразяться дані лише за стільки років, яке значення подане в комірці L3.

База для побудови графіків готова.

А тепер зазирнімо в майбутнє

Погляньте на малюнок 4. Саме так виглядає динаміка зміни амортизації і залишкової вартості об'єкта основних засобів при використанні всіх методів. Погодьтеся, дуже наочно.

Малюнок 4


1 Ми трохи відійшли від рекомендацій Стандарту, у якому запропоновано оперувати місячними обсягами. Однак на результат аналізу, у якому використані річні суми амортизації, це не вплине.

Для побудови графіка зміни річної амортизації, показаного на мал. 4, виділіть масив С12:Н19 і натисніть кнопку "Майстер діаграм" . Потім виберіть тип діаграми (для цієї мети найбільш придатний тип - "Графік", мал. 5) - і можна натискати кнопку "Готово". Щоб зробити діаграму максимально презентабельною, можна пройти всі стадії, які пропонує "Майстер діаграм".

Малюнок 5

Однак це не обов'язково. Єдина порада: якщо ви хочете розмістити графіки на окремому аркуші - встановіть перемикач "отдельно" у вікні "Майстра" (мал. 6).

Малюнок 6

Будь-які зміни у представлення одержаних графіків можна внести після їх створення. Для цього досить виділити необхідну ділянку графіка (при цьому на її контурі з'являються маркери виділення) і за допомогою контекстного меню внести потрібні доповнення.

Побудовані таким чином графіки є інтерактивними і при зміні вихідних даних, що впливають на розрахунки, автоматично відслідковуватимуть зміни результату.

Проробивши роботу, описану в цьому уроці ви одержите могутній інструмент для аналізу й коригування вашої амортизаційної політики. На наступному уроці ви довідаєтеся, як автоматизувати розрахунок амортизації в будь-якому звітному періоді, включаючи варіанти виведення об'єкта ОЗ з експлуатації та в разі переоцінки.

© 2001
"Дебет-Кредит"
Редакція: debet-kredit@gc.kiev.ua