Дебет-Кредит
Украинский бухгалтерский еженедельник
#22 '2001: Практичная бухгалтерия - Автоматизация бухучета: Excel

Автоматизация бухучета:
Бухгалтерский учёт с помощью Excel.
12-й урок

Заполнение, учет и хранение платежных документов с помощью EXCEL

Владимир ЛАВРЕНОВ


Предыдущие уроки "Автоматизации бухучёта: Excel"

На предыдущем уроке вы ознакомились с основным принципом создания и хранения платежных документов в excel-формате. Сегодня рассмотрим приемы и особенности автоматизации заполнения платежного поручения, хранения его в электронной форме.

Заполняем Журнал регистрации Блок "Получатель"

Как было сказано в 11-м уроке, в блоке "Получатель" Журнала регистрации графы 6, 7, 8, 9, 10, 11 заполняются с помощью формул. Приведенная в конце прошлого урока формула записи наименования получателя платежа, надеемся, не вызвала у вас непонимание. Рассмотрим данную формулу, скопированную в ячейку F7 (рис.1).

Рисунок 1.

=ЕСЛИ(ИЛИ(ЕПУСТО(A7);ЕПУСТО(B7);

ЕПУСТО(C7);ЕПУСТО(D7));””;ЕСЛИ(C7=”К”;
ВПР(D7;Контрагент;3;ЛОЖЬ);
ЕСЛИ(ИЛИ(C7=”Б”;E7=”БК”);
ВПР(D7;Бюджет;3;ЛОЖЬ)))).

Приведенная формула состоит из трех условий.

Первое условие:

"ЕСЛИ(ИЛИ(ЕПУСТО(A7);ЕПУСТО(B7);ЕПУСТО(C7);ЕПУСТО(D7));””"

обеспечивает проверку внесения исходных данных в 4 ячейки блока "Данные для заполнения" (графы 1, 2, 3, 4).

То есть если хотя бы в одну из ячеек A6, B6, C7, D7 (это условие обеспечивается функцией ИЛИ) не внести данные, то в ячейку F7 не будет записано наименование получателя (рис. 2).

Рисунок 2.

В приведенном условии впервые использована функция ЕПУСТО (категория Проверка свойств и значений в окне Мастер функций). В данном случае функция ЕПУСТО(С7) возвращает значение ИСТИНА, так как проверяемое значение является ссылкой на пустую ячейку С7. А поскольку в данном примере значению ИСТИНА соответствует "””", о в ячейку F7 записан пробел.

Следует обратить внимание на одну особенность использования функции ЕПУСТО. Отсутствие значения в ячейке не означает, что она пуста. Если в ячейку будет внесена формула, которая не будет возвращать какое-либо значение, то функция ЕПУСТО возвратит значение ЛОЖЬ. Например, пускай в ячейку А6 введена формула =ЕСЛИ(ЕПУСТО(А7);””;А7) (рис. 2). И если в ячейку А7 не записано значение, то в ячейке А6 тоже не будет никакого значения (рис. 2). Тем не менее в ячейку F6 наименование получателя будет внесено. Для нашего варианта эта ситуация маловероятна, однако в других случаях учитывайте это обстоятельство.

Второе условие:

"ЕСЛИ(C7=”К”;ВПР(D7;Контрагент;3;ЛОЖЬ)"

обеспечивает внесение в ячейку F7 наименования получателя из Перечня контрагентов (лист Контрагент), если в ячейку С7 записан символ "К".

Внимание! В формуле наподобие С7=”К” символы К, Б, БК обязательно должны быть в кавычках.

Третье условие:

"ЕСЛИ(ИЛИ(C7=”Б”;E7=”БК”);ВПР(D7;Бюджет;3;ЛОЖЬ))"

обеспечивает внесение в ячейку F7 наименования получателя из Перечня платежей (лист Бюджет), если в ячейку С7 записан символ "Б" или символы "БК".

Формулы, которые необходимо ввести в ячейки остальных граф блока Получатель, абсолютно подобны приведенной выше.

Незначительное отличие заключается в третьем аргументе функции ВПР.

В формуле функция ВПР используется дважды; если введен символ "К" - используются реквизиты из Перечня контрагентов, если введен символ "Б" или "БК" - из Перечня платежей. Третий аргумент этой функции соответствует номеру столбца в массиве одного из двух перечней.

Например, для внесения в ячейку G6 кода ЕГРПОУ получателя платежа, выбранного из Перечня контрагентов, функция (часть формулы) должна выглядеть следующим образом:

"ВПР(D6;Контрагент;4;ЛОЖЬ".

Третий аргумент функции ВПР (в данном случае - 4) указывает на номер столбца в Перечне контрагентов (массив Контрагент), в который записаны коды ЕГРПОУ (рис. 3).

Рисунок 3.

Аналогичный порядок внесения кода ЕГРПОУ, если получателем платежа является бюджетная организация или внебюджетный фонд. В этом случае в ячейку 3 графы Журнала, например, С7 записывается символ "Б". Функция ВПР должна быть следующей:

"ВПР(D7;Бюджет;4;ЛОЖЬ)". Как видно на рисунке 4, в Перечне платежей коды ЕГРПОУ организаций находятся в столбце №4.

Рисунок 4.

Полная формула для ячеек 7 графы Журнала следующая (вариант для ячейки G7):

=ЕСЛИ(ИЛИ(ЕПУСТО(A7);ЕПУСТО(B7);ЕПУСТО(C7);ЕПУСТО(D7));””;
ЕСЛИ(C7=”К”;ВПР(D7;Контрагент;4;ЛОЖЬ);
ЕСЛИ(ИЛИ(C7=”Б”;E7=”БК”);ВПР(D7;Бюджет;4;ЛОЖЬ)))).

Чтобы не вводить в ячейки других граф блока "Получатель" подобные формулы, единственное отличие которых - значение 3-го аргумента в функции ВПР, поступите следующим образом:

1. Дважды щелкните ЛКМ на ячейке F6 (в нее должна быть введена формула).

2. Выделите появившуюся в ячейке формулу и скопируйте ее, вызвав контекстное меню (рис. 5).

Рисунок 5.

3. Вернитесь к активной ячейке F6 нажатием клавиши Esc или кнопки Отмена ввода формулы.

4. Перейдите в ячейку G6 и вставьте в нее скопированную формулу. Операцию Вставка повторите для ячеек H6, I6, J6, K6.

5. Откройте формулу в ячейке G6 и замените в двух функциях ВПР цифру "3" цифрой "4".

6. Соответствующее редактирование проведите в других ячейках. В ячейке H6 вместо "3" - "5", в I6 - "6", в J6 - "7", в K6 - "8".

7. Копирование введенных формул лучше произвести после заполнения формулами всех ячеек первой строки Журнала

Блок "Получатель" готов к работе.

Блок "Коды бюджетных платежей"

Как уже было сказано выше, данные этого блока используются для заполнения реквизита "Назначение платежа" при бюджетных и внебюджетных платежах.

Такая запись должна содержать служебный код (*); идентификационный код вашего предприятия; код платежа, в соответствии с классификацией доходов бюджета, и код вида уплаты, разделенных точкой с запятой (урок 11).

Для упрощения формулы, с помощью которой в платежном документе заполняется реквизит "Назначение платежа", в ячейках Журнала следует записать готовые фрагменты этого реквизита (т. е. с разделительными символами).

1. Запишите в ячейку L6 формулу:

"=ЕСЛИ(ИЛИ(C6=”Б”;C6=”БК”);”*”&”;”&Контрагент!$D$6;””)", которая обозначает:

- если в ячейку C6 записан символ Б или БК, в ячейке L6 появится запись из трех элементов: звездочки (*), точки с запятой (;) и кода вашего предприятия, который записан в Перечне контрагентов (лист Контрагент) в ячейке D6. Ссылка на эту ячейку - абсолютная (символ $), с тем чтобы при копировании формулы она не изменилась (рис. 6);

Рисунок 6.

- если символ отсутствует или записан любой другой, в ячейку L6 вернется пробел.

Введенная формула возвратит значение типа: "*;ХХХХХХХХ".

2. Запишите в ячейку М6 формулу:

=ЕСЛИ(ИЛИ(C6=”Б”;C6=”БК”);”;”&ВПР(D6;Бюджет;9;ЛОЖЬ)&”;”;””)

В этой формуле используются только относительные ссылки, так как при копировании формулы, например, в ячейку М7 она должна выглядеть следующим образом:

=ЕСЛИ(ИЛИ(C7=”Б”;C7=”БК”);”;”&ВПР(D7;Бюджет;9;ЛОЖЬ)&”;”;””).

Приведенная формула возвратит значение типа: ";ХХХХХХ;"

3. Запишите в ячейку О6 формулу:

=ЕСЛИ(ЕПУСТО(E6);””;ЕСЛИ(C6=”БК”;”;
(”&ВПР(E6;Контрагент;4;ЛОЖЬ)&”);”))

В формулу введено дополнительное условие "ЕСЛИ(ЕПУСТО(E6);””", так как эта ячейка заполняется, если платеж осуществляется за вашего контрагента. В ячейку Е6 должен быть введен номер контрагента, в противном случае в ячейку О6 вернется пробел.

С помощью аргумента "”;(“&ВПР(E6;Контрагент;4;ЛОЖЬ)&”)”" будет записан текст типа: ";(ХХХХХХХХ)".

Блок Коды бюджетных платежей готов.

Блок "Платеж"

В этом блоке две графы заполняются автоматически: графа 18 (Сумма прописью) и графа 20 (Сумма НДС). Для заполнения графы 20 введите в ячейку Т6 (рис. 7) формулу:

=ЕСЛИ(ИЛИ(ЕПУСТО(G6);C6=”Б”;C6=”БК”);””;ЕСЛИ(И(C6=”К”;ЕПУСТО(S6));” без податку на додану вартість.”;” у т.ч.ПДВ =”&РУБЛЬ(Q6/6;2)))

Рисунок 7.

Первое условие

"ЕСЛИ(ИЛИ(ЕПУСТО(G6);C6=”Б”;C6=”БК”);””" обеспечивает выполнение требования Инструкции НБУ - при уплате бюджетных налогов и сборов НДС не выделяется.

Второе условие

ЕСЛИ(И(C6=”К”;ЕПУСТО(S6)) означает, что в ячейку Т6 будет записан текст "без податку на додану вартість.", если в ячейку С6 ввести символ "К", а ячейку S6 оставить пустой. Если в ячейку S6 ввести любой символ, в ячейке Т6 появится текст "у т.ч.ПДВ =ХХ,хх грн.".

Для расчета суммы НДС используется аргумент "РУБЛЬ(Q6/6;2)".

Функция РУБЛЬ преобразует число в текст, используя денежный формат. Чтобы установить обозначение валюты "грн.", установите нужное обозначение в поле Обозначение на вкладке Число (рис. 7). Если после значения (Q6/6) не ставить количество десятичных знаков после запятой (в примере - 2), то результат округляется до 2-го десятичного знака. Поэтому второй аргумент в этой функции можно не использовать - "РУБЛЬ(Q6/6)".

Как записать сумму платежа прописью

К сожалению стандартные средства Microsoft не дают возможность преобразовать записанное цифрами число в текст. Приведенная функция РУБЛЬ, как и другие из набора Excel, не решают эту проблему. Некоторые компьютерные фирмы предлагают готовые программы специально по этой теме. Однако мы решим эту задачу в рамках создаваемой нами системы.

Для этого потребуется немного усилий.

В книге Документ откройте лист Табло, на котором заполните приведенную на рисунке 8 таблицу. Выделите ячейки А4:Е12 и введите в поле имен имя Табло. Данные из этой таблицы будут использоваться в формулах перевода цифровой записи суммы платежа в текстовую.

Рисунок 8.

В чем суть системы перевода цифр в пропись:

1. Нужно разбить сумму по разрядам.

2. Величину отдельного разряда записать текстом.

3. Соединить эти тексты в одну строку.

А эти небольшие задачки уже решаются с помощью известных вам формул.

Для этого на листе Регистр с правой стороны от Журнала регистрации создайте таблицу (рис. 9). Она состоит из двух частей: Разряды и Сумма прописью.

Рисунок 9.

Первая строка таблицы должна совпадать с первой строкой Журнала.

Первая часть таблицы содержит 6 граф, что позволит записать прописью сумму, равную 999999,99 грн.

Осталось ввести формулы в ячейки первой строки таблицы (строка №6).

Формулы просты, и в них вы легко увидите определенную закономерность:

ячейка V6 =ЕСЛИ(Q6>=100000;ЦЕЛОЕ(Q6/100000);0);
ячейка W6 =ЕСЛИ(Q6>=10000;ЦЕЛОЕ(Q6/10000)-
(ЦЕЛОЕ(Q6/100000))*10;0);
ячейка X6 =ЕСЛИ(Q6>=1000;ЦЕЛОЕ(Q6/1000)-(ЦЕЛОЕ(Q6/10000))*10;0);
ячейка Y6 =ЕСЛИ(Q6>=100;ЦЕЛОЕ(Q6/100)-(ЦЕЛОЕ(Q6/1000))*10;0);
ячейка Z6 =ЕСЛИ(Q6>=10;ЦЕЛОЕ(Q6/10)-(ЦЕЛОЕ(Q6/100))*10;0);
ячейка AA6 =ЕСЛИ(Q6>=1;ЦЕЛОЕ(Q6)-(ЦЕЛОЕ(Q6/10))*10;0).

Внимание! В каждой формуле последний аргумент обязательно должен быть равен нулю (0).

Вторая часть состоит из двух разделов.

В ячейки первого раздела записываются разряды прописью.

В ячейках второго раздела формируется текстовой ряд суммы прописью в том виде, в котором она будет вноситься в платежное поручение:

- высший разряд суммы из графы 17 записывается с ПРОПИСНОЙ буквы;

- если необходимо, добавляется слово "тисяча" (в нужном числе);

- добавляется текстовая группа "грн. ХХ коп.".

Использование двух этапов перевода числа в текст вызвано:

- необходимостью упрощения формулы (в одной формуле можно использовать не более 8 логических функций ЕСЛИ);

- функция ПРОПИСН, с помощью которой можно ввести слово с прописной буквы, некорректно распознает в словах апостроф. Например, если записать в ячейку формулу =ПРОПИСН(п'ять), вернется результат П'Ять.

Итак, в ячейки АВ6:AG6 вводим следующие формулы:
в ячейку АВ6: =ЕСЛИ(V6=0;””;ВПР(V6;Табло;5;ЛОЖЬ));
в ячейку АС6: =ЕСЛИ(W6=0;””;ЕСЛИ(И(W6=1;X6>0);
ВПР(X6;Табло;3;ЛОЖЬ);ВПР(W6;Табло;4;ЛОЖЬ)));
в ячейку AD6: =ЕСЛИ(X6=0;””;ЕСЛИ(X6>0;ВПР(X6;Табло;2;ЛОЖЬ)));
в ячейку АЕ6: =ЕСЛИ(Y6=0;””;ЕСЛИ(Y6>0;ВПР(Y6;Табло;5;ЛОЖЬ)));
в ячейку АF6: =ЕСЛИ(Z6=0;””;ЕСЛИ(И(Z6=1;AA6>0);ВПР(AA6;
Табло;3;ЛОЖЬ);ВПР(Z6;Табло;4;ЛОЖЬ)));
в ячейку AG6: =ЕСЛИ(AA6=0;””;=ЕСЛИ(И(Q6>0;Q6<1);
"Нуль";ЕСЛИ(Z6=1;"";ЕСЛИ(AA6>0;
ВПР(AA6;Табло;2;ЛОЖЬ);""))
)

Как видите, эти формулы тоже довольно просты.

И, наконец, получаем сумму прописью, разбитую на разряды по ячейкам. Для этого запишите:

в ячейку AI6: =ЕСЛИ(V6=0;””;ЕСЛИ(V6=5;”П'ятсот”;
ЕСЛИ(V6=9;”Дев'ятсот”;ПРОПНАЧ(AB6))));
в ячейку AJ6: =ЕСЛИ(V6>0;AC6;ЕСЛИ(ЦЕЛОЕ(Q6/1000)=15;
”П'ятнадцять”;
ЕСЛИ(ЦЕЛОЕ(Q6/1000)=19;”Дев'ятнадцять”;
ЕСЛИ(ЦЕЛОЕ(Q6/10000)=5;”П'ятдесят”;
ЕСЛИ(ЦЕЛОЕ(Q6/10000)=9;”Дев'яносто”;
ПРОПНАЧ(AC6)))));
в ячейку AK6: =ЕСЛИ(ИЛИ(W6=1;X6=0);””;ЕСЛИ(ЦЕЛОЕ(Q6/1000)>9;AD6;
ЕСЛИ(ЦЕЛОЕ(Q6/1000)=5;”П'ять”;
ЕСЛИ(ЦЕЛОЕ(Q6/1000)=9;”Дев'ять”;ПРОПНАЧ(AD6)))));
в ячейку AL6: =ЕСЛИ(И(V6=0;W6=0;X6=0);””;ЕСЛИ(X6=1;
”тисяча”;ЕСЛИ(И(X6>1;X6<5);”тисячі”;”тисяч”)));
в ячейку AM6: =ЕСЛИ(Y6=0;””;ЕСЛИ(ЦЕЛОЕ(Q6/100)>9;AE6;
ЕСЛИ(И(Q6<1000;Y6=5);”П'ятсот”;
ЕСЛИ(И(Q6<1000;Y6=9);”Дев'ятсот”;ПРОПНАЧ(AE6)))));
в ячейку AN6: =ЕСЛИ(ЦЕЛОЕ(Q6/10)>9;AF6;
ЕСЛИ(ЦЕЛОЕ(Q6)=15;”П'ятнадцять”;
ЕСЛИ(ЦЕЛОЕ(Q6)=19;”Дев'ятнадцять”;
ЕСЛИ(ЦЕЛОЕ(Q6/10)=5;”П'ятдесят”;
ЕСЛИ(ЦЕЛОЕ(Q6/10)=9;”Дев'яносто”;ПРОПНАЧ(AF6))))));
в ячейку AO6: =ЕСЛИ(ЦЕЛОЕ(Q6)>9;AG6;ЕСЛИ(ЦЕЛОЕ(Q6)=5;”П'ять”;
ЕСЛИ(ЦЕЛОЕ(Q6)=9;”Дев'ять”;ПРОПНАЧ(AG6))));
в ячейку AP6: =ЕСЛИ(Q6-ЦЕЛОЕ(Q6)=0;"грн 00 коп.";ЕСЛИ(AG6="Нуль";
"гривень "&ЦЕЛОЕ(Q6*100-ЦЕЛОЕ(Q6)*100)&" коп.";
ЕСЛИ(ЦЕЛОЕ(Q6*100-ЦЕЛОЕ(Q6)*100)<10;
"грн "&"0"&ЦЕЛОЕ(Q6*100-ЦЕЛОЕ(Q6)*100)&" коп.";
"грн "&ЦЕЛОЕ(Q6*100-ЦЕЛОЕ(Q6)*100)&" коп.")))

Осталось заполнить в Журнале регистрации последнюю, 18-ю, графу. Она была предварительно скрыта.

Чтобы записать всю сумму прописью, введите в ячейку R6 формулу (рис. 10):

=ЕСЛИ(ЕПУСТО(Q6);””;AI6&” ”&AJ6&” ”&AK6&” ”&AL6&”
 ”&AM6&” ”&AN6&” ”&AO6&” ”&AP6),

которая последовательно связывает все элементы текста суммы.

Рисунок 10.

В приведенной формуле символы ” ” (между кавычками - пробел) обеспечивают пробелы между словами.

Выделите ячейки F6:АР6 и скопируйте их до 106 строки (условно предложенный интервал, позволяющий создать 100 платежных документов).

Внимание! Ячейки, в которые не вводятся формулы (N6, P6, Q6, S6), должны быть пустыми.

Журнал регистрации готов для выполнения своих функций.

Заполняем платежное поручение

На рисунке 11 фоном закрашены ячейки, которые заполняются с помощью формул.

Рисунок 11.

В ячейки, содержащие реквизиты плательщика, необходимо ввести следующие формулы:

D6: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(1;Контрагент;3;ЛОЖЬ));
C8: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(1;Контрагент;4;ЛОЖЬ));
E10: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(1;Контрагент;5;ЛОЖЬ));
E12: =ЕСЛИ(ЕПУСТО(G2);””;”в м. ”&ВПР(1;Контрагент;6;ЛОЖЬ));
I11: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(1;Контрагент;7;ЛОЖЬ));
N11: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(1;Контрагент;8;ЛОЖЬ));

Как видите, формулы, записывающие реквизиты плательщика, отличаются только третьим аргументом в функции ВПР (закрашено фоном), в которой используется массив Контрагент. Поэтому достаточно ввести одну формулу в ячейки D6, C8, E10, E10, E12, I11, N11 и затем отредактировать их.

Остальные формулы подобны приведенным, отличаясь от них аргументом Регистр в функции ВПР. Введите в ячейку Е3, в которую записывается дата документа, формулу:

=ЕСЛИ(ЕПУСТО(G2);””;ВПР(G2;Регистр;2;ЛОЖЬ)).

Теперь скопируйте эту формулу в приведенные ниже ячейки, отредактировав в функции ВПР третий аргумент:

D14: =ЕСЛИ(ЕПУСТО(G2);””;(ВПР(G2;Регистр;6;ЛОЖЬ)));
C16: =ЕСЛИ(ЕПУСТО(G2);””;(ВПР(G2;Регистр;7;ЛОЖЬ)));
E18: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(G2;Регистр;8;ЛОЖЬ));
E20: =ЕСЛИ(ЕПУСТО(G2);””;”в м. “&ВПР(G2;Регистр;9;ЛОЖЬ));
I19: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(G2;Регистр;10;ЛОЖЬ));
N19: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(G2;Регистр;11;ЛОЖЬ));
Q11: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(G2;Регистр;17;ЛОЖЬ));
E21: =ЕСЛИ(ЕПУСТО(G2);””;ВПР(G2;Регистр;18;ЛОЖЬ));

Внимание! Формулы ячеек E12 и E20 отличаются от остальных дополнительно введенным аргументом "”в м. “&".

Так как содержание текста назначения платежа зависит от нескольких факторов, формула для его записи отличается от предыдущих.

В ячейку F23 нужно записать:

=ЕСЛИ(ЕПУСТО(G2);””;ЕСЛИ(ЛЕВСИМВ(ВПР(G2;Регистр;3;ЛОЖЬ);
1)=”Б”;ВПР(G2;Регистр;12;ЛОЖЬ)&ВПР(G2;Регистр;13;ЛОЖЬ)
&ВПР(G2;Регистр;14;ЛОЖЬ)&”;”&ВПР(G2;Регистр;15;ЛОЖЬ)
&ВПР(G2;Регистр;16;ЛОЖЬ);ЕСЛИ

(ВПР(G2;Регистр;3;ЛОЖЬ)=”К”;ВПР(G2;Регистр;16;ЛОЖЬ)
&ВПР(G2;Регистр;20;ЛОЖЬ)))).

Если разобраться, формула совершенно не- сложная. После выполнения одного из двух логических условий: "ЕСЛИ(ЛЕВСИМВ(ВПР(G2;Регистр;3;ЛОЖЬ);1)=”Б”" или "ЕСЛИ(ВПР(G2;Регистр;3;ЛОЖЬ)=”К”", последовательно сцепляются в одну текстовую строку данные из соответствующих ячеек Журнала регистрации.

Синтаксис формулы следующий:

- если первым левым символом (ЛЕВСИМВ(ВПР(G2;Регистр;3;ЛОЖЬ);1)) из ячейки 3 графы Журнала регистраций (ЛЕВСИМВ(ВПР(G2;Регистр;3;ЛОЖЬ);1)) является "Б", то сцепляются данные ячеек из граф 12, 13, 14, 15, 16;

- если в ячейку графы 3 введен символ "К", то сцепятся данные из граф 16 и 20.

Внимание! Во всех приведенных формулах можно убрать логическое условие "ЕСЛИ(ЕПУСТО(G2);””;". В этом случае, до ввода в платежное поручение его номера, во всех ячейках будет возвращено значение "#Н/Д".

Итак, вся система создания и сохранения платежных документов готова к работе.

Как подготовить платежное поручение

Если вы предварительно ввели необходимые реквизиты получателя и, конечно, своего предприятия, то последовательность заполнения платежного поручения №1 будет следующей (рис.12):

1) введите в ячейку А6 порядковый номер платежного документа;

2) в ячейке В6 должна быть дата составления документа. Если вы заблаговременно готовите документы для банка, то в эту ячейку желательно ввести дату предоставления документа в банк;

3) в ячейку С6 вводится символ, который определяет вид платежа. Символы "К", "Б", "бк" можно вводить в любом регистре;

4) если вы готовите документ для оплаты операции по хозяйственному договору (символ "К"), то откройте лист Контрагент и выберите на нем порядковый номер получателя платежа (А7). Этот номер внесите в ячейку D6;

5) в ячейку F6 введите только текстовую часть назначения платежа.

6) в ячейку Q6 введите сумму платежа;

7) если в платежном поручении необходимо выделить НДС, в ячейку S6 введите любой печатный символ (например, 1).

Рисунок 12.

Этим этапом фактически заканчивается процедура сохранения платежного документа.

Создание самого документа заключается только во введении в ячейку G2 на листе Платеж символа, который записан в Журнале в ячейку графы 1. Например, для создания платежного поручения, показанного на рисунке 11, данные которого записаны в ячейки 6 строки, достаточно ввести в ячейку G2 символ 1). Платежное поручение готово к печати.

На следующем уроке вы ознакомитесь с порядком создания требования-поручения и корректировкой формы платежного поручения в соответствии с новой Инструкцией Нацбанка "О безналичных расчетах в Украине в национальной валюте".


Следующий урок

© 2001
"Дебет-Кредит"
Редакция: debet-kredit@gc.kiev.ua